IEC2671A START X'00'                                                    00020000
*084135000,35200,53000,53200,53400                                 7884 00030017
*43100,43200,43300,50200,50400                                     8655 00040017
         SPACE 2                                                        00060000
*                   2671 ERROR RECOVERY PROCEDURE                       00080000
         SPACE 1                                                        00100000
*      FUNCTION     ANALYSE STATUS AND SENSE DATA AND ATTEMPT ERROR     00120000
*                   RECOVERY. IF THE ERROR IS CORRECTED,PROCEED IN A    00140000
*                   NORMAL MANNER. IF A PERMANENT ERROR IS DETECTED     00160000
*                   INDICATE IT TO THE USER BY A COMPLETION CODE IN THE 00180000
*                   ECB AND A MESSAGE ON THE SYSTEM CONSOLE.            00200000
*         ENTRY:    ER2671    FROM INTERRUPT SUPERVISOR                 00220000
*         INPUT     REQUEST ELEMENT POINTER IN REGISTER 1               00240000
*        OUTPUT     NONE                                                00260000
*       EXT REF     NONE                                                00280000
*         EXITS     1. ERRECXP EXIT TO I/O SUPERVISOR TO RE-EXECUTE     00300000
*                      THE CHANNEL PROGRAM IN ERROR.                    00320000
*                   2. SVC 3 EXIT TO RETURN CONTROL TO THE SUPERVISOR   00340000
*                      AND RELINQUISH CONTROL OVER THE TRANSIENT AREA   00360000
*                   3. XCTL EXIT TO OUTBOARD RECORDING, STATISTICS UP-  00380000
*                      DATE OR WRITE TO OPERATOR. RETURN WILL BE MADE   00400000
*                      FROM THESE ROUTINES TO THE SUPERVISOR VIA SVC 3. 00420000
*       ERR MSGS    CONSOLE MESSAGES TO INDICATE ERROR CONDITIONS ARE   00440000
*                        1. I/O ERR                                     00460000
*                        2. INT REQ                                     00480000
*         NOTES     IOB EXCEPTION AND IOB ERROR FLAGS ARE INTERPRETED   00500000
*                   AS FOLLOWS                                          00520000
*                        IOBEX ON AND IOBERR ON, ERR RTNE IN CONTROL.   00540000
*                        IOBEX ON AND IOBERR OFF, PERMANENT ERROR.      00560000
*                        IOBEX OFF AND IOBERR OFF, NO ERR OR CORRECTED  00580000
*        TABLES     STATISTICS TABLE AND IOB                            00600000
*     OPERATION     THIS ROUTINE CHECKS THE STATUS AND SENSE BYTES      00620000
*                   STORED IN THE UCB AND IOB AND TAKES ACTION AS       00640000
*                   SPECIFIED IN THE DEVICE STANDARDS. STATISTICS ARE   00660000
*                   KEPT AS TO THE KIND AND FREQUENCY OF ERRORS. THESE  00680000
*                   STATISTICS ARE USED BY THE CE TO ISOLATED AND       00700000
*                   RECOGNIZE ERRORS.                                   00720000
*                   A COMMON INTERPRETER ROUTINE IS USED TO CHECK BOTH  00740000
*                   STATUS AND SENSE. ON RETURN FROM THE INTERPRETER    00760000
*                   THE PROPER ACTION OF RETRY, RETURN OR WRITE A       00780000
*                   MESSAGE TO THE OPERATOR IS TAKEN.                   00800000
         EJECT                                                          00820000
*        TITLE  ' INPUT OUTPUT CONTROL BLOCK (IOB) '                    00840000
         SPACE 2                                                        00860000
*               *****************************************               00880000
*               *    *    *         *    *              *               00900000
*             0 *FLG1*FLG2*  SENSE  *ECB *   ECB PTR    *               00920000
*               *    *    *         *CODE*              *               00940000
*               *****************************************               00960000
*               *                                       *               00980000
*             8 *        CHANNEL  STATUS  WORD          *               01000000
*               *                                       *               01020000
*               *****************************************               01040000
*               *    *              *         *         *               01060000
*            16 * CC *    START     *WGHT*   DCB PTR    *               01080000
*               *    *              *    *              *               01100000
*               *****************************************               01120000
*               *    *              *    *              *               01140000
*            24 *MODF*   RESTART    * INCR (2)* ERR CNTS*               01160000
*               *    *              *    *TP 1*         *               01180000
*               *****************************************               01200000
*               *                                       *               01220000
*            32 *  M *  B *  B *  C *  C *  H *  H *  R *               01240000
*               *                                       *               01260000
*               *****************************************               01280000
         SPACE 2                                                        01300000
*              IOB DEFINITION                                           01320000
         SPACE 1                                                        01340000
IOBFL1   EQU   0                        FLAGS 1                         01360000
IOBFL2   EQU   1                        FLAGS 2                         01380000
IOBSNS   EQU   2                        SENSE DATA                      01400000
IOBCOD   EQU   4                        ECB CODE                        01420000
IOBFL3   EQU   8                        IOB FLAG NO 3                   01440000
IOBCSW   EQU   8                        CSW STORAGE                     01460000
IOBCC    EQU   16                       CONDITION CODE                  01480000
IOBST    EQU   17                       START ADDRESS                   01500000
IOBDCB   EQU   21                       DCB POINTER                     01520000
IOBMDB   EQU   24                       MODIFIER BYTE                   01540000
IOBRST   EQU   25                       RESTART POINTER                 01560000
IOBBCI   EQU   28                       BLOCK COUNT INCR.               01580000
IOBTPM   EQU   29                       T.P. EXTENT (M) BYTE            01600000
IOBECT   EQU   30                       ERROR COUNTS                    01620000
         SPACE 2                                                        01640000
*   THESE FLAGS ARE IN IOB FLAG 1                                       01660000
IOBCP1   EQU   X'80'                    TYPE OF CHANNEL PROGRAM         01680000
IOBCP2   EQU   X'40'                    TYPE OF CHANNEL PROGRAM         01700000
IOBERR   EQU   X'20'                    IOB ERROR FLAG                  01720000
IOBMD1   EQU   X'10'                    MOD1 FLAG - POSITIONING         01740000
IOBMD2   EQU   X'08'                    MOD 2 FLAG - CRC                01760000
IOBEX    EQU   X'04'                    EXCEPT FLAG                     01780000
IOBSRS   EQU   X'01'                    START/RESTART FLAG              01800000
IOBEXE   EQU   IOBEX+IOBERR             IOB EX + IOB ERROR FLAG         01820000
         SPACE 2                                                        01840000
*   THESE FLAGS ARE IN IOB FLAG 2                                       01860000
IOBHLT   EQU   X'80'                    HALT I/O ISSUED FLAG            01880000
         SPACE 2                                                        01900000
*   THESE FLAGS ARE IN IOB FLAG 3                                       01920000
IOBENT   EQU   X'80'                    ENTRY FLAG                 8655 01930017
ECKCNT   EQU   X'60'                    EQUIPMENT CHECK MAX. COUNT      01940000
IOBBOE   EQU   X'10'                    BUS OUT ERROR CNT               01960000
IOBMSG   EQU   X'04'                    MESSAGE TYPE                    01980000
IOBLOG   EQU   X'01'                    LOGOUT FLAG                     02000000
         SPACE 2                                                        02020000
*   REGISTER DEFINITIONS                                                02040000
ERREG3   EQU   0                        WORK REG 3                      02060000
TSTREG   EQU   1                        TWELVE STAR REG                 02080000
ERREG2   EQU   2                        WORK REG.                       02100000
CRBREG   EQU   3                        CURRENT RB REG.                 02120000
CCWREG   EQU   4                        CCW ADDRESS REG                 02140000
ERPIBRG  EQU   6                        ERPIB PTR REG              CCHA 02150016
UCBREG   EQU   7                        UCB ADDRESS REG                 02160000
COMREG   EQU   8                        COMMUNICATION TABLE REG         02180000
SAVREG   EQU   9                        SAVE REG.                       02200000
IOBRG    EQU   10                       IOB ADDRESS REG                 02220000
ERREG4   EQU   11                       WORK REG                        02240000
ERRLNK   EQU   12                       LINK REG                        02260000
ERREG1   EQU   13                       WORK REG 1                      02280000
ERRETR   EQU   14                       RETURN REG                      02300000
BASREG   EQU   15                       BASE REG.                       02320000
         SPACE 2                                                        02340000
*              TWELVE STAR DEFINITION                                   02360000
TSTLNK   EQU   0                        FORWARD 12* LINK                02380000
TSTUCB   EQU   2                        UCB POINTER                     02400000
TSTIOB   EQU   5                        IOB POINTER                     02420000
TSTDEB   EQU   9                        DEB POINTER                     02440000
         SPACE 2                                                        02460000
*              ECB DEFINITIONS                                          02480000
ECBFL    EQU   0                        FLAGS                           02500000
         SPACE 2                                                        02520000
*              DCB DEFINITION                                           02540000
DCBFL    EQU   44                       FLAGS                           02560000
DCBPER   EQU   X'C0'                    PERMANENT ERROR FLAGS           02580000
DCBEX    EQU   X'40'                    EXCEPTION CONDITION             02600000
         SPACE 2                                                        02620000
*   UCB DEFINITION                                                      02640000
UCBFL1   EQU   6                        UCB FLAG                        02660000
UCBSTI   EQU   9                        STATISTIC POINTER               02680000
UCBNRY   EQU   X'40'                    UCB NOT READY                   02700000
         SPACE 2                                                        02720000
*              STATUS INDICATORS                                        02740000
CSWCHE   EQU   X'08'                    CHANNEL END                     02760000
CSWUCK   EQU   X'02'                    UNIT CHECK                      02780000
CSWUEX   EQU   X'01'                    UNIT EXCEPTION                  02800000
CSWCCK   EQU   X'01'                    CHAINING CHECK                  02820000
CSWCDCK  EQU   X'08'                    CHANNEL DATA CHECK         CCHA 02825016
CSWCCCK  EQU   X'04'                    CHANNEL CNTRL CHECK        CCHA 02830016
CSWICCK  EQU   X'02'                    INTRFCE CNTRL CHECK        CCHA 02835016
         SPACE 2                                                        02840000
*              MISC. DEFINITIONS                                        02860000
ERRBLK   EQU   X'40'                    BLANK                           02880000
EIOBIN   EQU   X'20'                    BINARY MODE                     02900000
IOSTUS   EQU   X'10'                    STATUS BIT                      02920000
IOBCC1   EQU   X'10'                    CONDITION CODE OF SIO           02940000
IOCLBT   EQU   X'00'                    CLEAR BYTE                      02960000
         SPACE 2                                                        02980000
EXCPER   EQU   15                       ERROR EXCP                      03000000
LOC016   EQU   16                       COMMUNICATION TABLE             03020000
VECTXL   EQU   44                       XCTL INDEX                      03040000
VECT68   EQU   68                       INTERPRETER ROUTINE             03060000
VECT72   EQU   72                       WRITE TO OPERATOR ROUTINE       03080000
STATAB   EQU   112                      STATISTIC TABLE INDEX           03100000
WTORTN   EQU   253                      LOAD NAME TO WTO RTN.           03120000
STATUP   EQU   254                      STATISTIC UPDATE INDEX          03140000
IBPTR    EQU   116                      PTR TO PTR TO PTR TO ERPIB CCHA 03146016
ENDTBL   EQU   X'FF'                    END OF ERPIB TABLE         CCHA 03152016
NXT      EQU   2                        NEXT CONTROL ENTRY         256D 03154018
TFTYSX   EQU   256                      INCREMENT STAT INDEX       256D 03156018
         EJECT                                                          03160000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 03180000
*        ENTRY TO THE - 2 6 7 1 - ERROR RECOVERY ROUTINE              * 03200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 03220000
*        INTERPRETATION OF THE IOBEX AND IOBERR FLAGS IS AS FOLLOWS   * 03240000
*        IOBEX  ON       IOBERR  ON     ERROR ROUTINE HAS CONTROL     * 03260000
*        IOBEX  ON       IOBERR  OFF    PERMANENT ERROR               * 03280000
*        IOBEX  OFF      IOBERR  OFF    ERROR CORRECTED               * 03300000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 03320000
         SPACE 1                                                        03340000
         USING ER2671,15                                                03360000
ER2671   L     IOBRG,TSTIOB-1(TSTREG)   GET ADDRESS OF IOB              03380000
         LH    UCBREG,TSTUCB(TSTREG)    GET ADDRESS OF UCB              03400000
         L     COMREG,LOC016            GET ADDRESS OF COMM. TABLE      03420000
         OI    IOBFL1(IOBRG),IOBEXE     SET IOB EX AND ERR FLAGS ON     03440000
         TM    IOBFL1(IOBRG),IOBCP2     TEST FOR COMMAND CHAIN          03460000
         BC    8,ERR601                 NO-CHECK CH/INTFCE CNTL CK CCHA 03480016
         L     CCWREG,IOBCSW(IOBRG)     GET ADDRESS OF CCW              03540000
         LA    CCWREG,0(CCWREG)         CLEAR HIGH ORDER BYTE           03560000
         SH    CCWREG,ERRCN1            GO BACK ONE CCW                 03580000
         ST    CCWREG,IOBMDB(IOBRG)     PUT CCW ADDRESS INTO RESTART    03600000
         OI    IOBFL1(IOBRG),IOBSRS     SET RESTART FALG                03620000
ERR601   TM    IOBCSW+5(IOBRG),CSWCCCK+CSWICCK CH/INTFCE CNTL CK   CCHA 03628016
         BC    4+2+1,ERZERIB            YES-ZERO ERPIB             CCHA 03636016
         SPACE 1                                                        03644016
         TM    IOBCSW+5(IOBRG),CSWCCK   TEST IF CHAINING CK IS ON  CCHA 03652016
         BC    1,ERR611                 YES, INDICATE LOGOUT            03660000
         TM    IOBCSW+4(IOBRG),CSWUCK   TEST FOR UNIT CHECK             03680000
         BC    8,ERR615                 NO, CHECK STATUS INFORMTION     03700000
         SPACE 1                                                        03720000
*        INFORMATION FOR STATISTICS IS OBTAINED FROM SENSE BYTE 0       03740000
*        AND IS STORED IN THE WORK AREA OF THE STATISTIC TABLE          03760000
         SPACE 1                                                        03780000
         L     ERREG2,STATAB(COMREG)    GET STATISTIC TABLE ADDRESS     03800000
         SR    ERREG4,ERREG4                                            03808018
         IC    ERREG4,UCBSTI(UCBREG)    GET STAT. TAB INDEX        256D 03816018
         LR    ERREG1,ERREG2            GET STAT. TAB START ADR    256D 03824018
ERRLOOP1 CH    UCBREG,0(0,ERREG1)       DEV SUPPORTED BY THIS SECT 256D 03832018
         BC    4,ERRLOOP2           YES,INCR ADJUSTED CORRECTLY    256D 03840018
         LA    ERREG1,NXT(0,ERREG1)     INCR TO NXT CTL SECTION    256D 03848018
         LA    ERREG4,TFTYSX(0,ERREG4)  INCR STAT INDEX TO NXT SECT256D 03856018
         BC    15,ERRLOOP1              LOOP TO CHECK THIS SECT    256D 03864018
         SPACE 1                                                        03872018
ERRLOOP2 MH    ERREG4,ERRCN2            MULTIPLY BY 10             256D 03880018
         AR    ERREG2,ERREG4            ADD TO TABLE ADDRESS       256D 03888018
         OC    8(1,ERREG2),IOBSNS(IOBRG) OR SENSE BYTE INTO TABLE       03900000
         NI    8(ERREG2),X'78'          MASK OUT UNWANTED BITS          03920000
         SPACE 1                                                        03940000
*        LINK TO THE INTERPRETER ROUTINE - THE BYTES FOLLOWING THE BALR 03960000
*        INDICATE IN WHAT ORDER THE BITS ARE TO BE TESTED (BIT 3 ON OF  03980000
*        THE CODE BYTE INDICATES STATUS) FOLLOWED BY AN INDEX VALUE THE 04000000
*        INTERPRETER USES TO RETURN TO THIS ROUTINE                     04020000
         SPACE 1                                                        04040000
         LR    SAVREG,BASREG            SAVE BASE ADDRESS               04060000
         L     BASREG,VECT68(COMREG)    GET ADDRESS OF INTERPRETER RTN. 04080000
ERR604   BALR  ERRLNK,BASREG            LINK TO INTERPRETER ROUTINE     04100000
         SPACE 1                                                        04120000
         DC    X'05'                    SHOULD NOT OCCUR                04140000
         DC    AL1(ERR611-ERR604-2)                                     04160000
         DC    X'06'                    SHOULD NOT OCCUR                04180000
         DC    AL1(ERR611-ERR604-4)                                     04200000
         DC    X'07'                    SHOULD NOT OCCUR                04220000
         DC    AL1(ERR611-ERR604-6)                                     04240000
         DC    X'03'                    EQUIPMENT CHECK          A30855 04260019
         DC    AL1(ERR611-ERR604-8)                              A30855 04280019
         DC    X'01'                    INTERVENTION REQUIRED    A30855 04300019
         DC    AL1(ERR608-ERR604-10)                             A30855 04320019
         DC    X'02'                    BUSOUT CHECK                    04340000
         DC    AL1(ERR609-ERR604-12)                                    04360000
         DC    X'04'                    DATA CHECK                      04380000
         DC    AL1(ERR611-ERR604-14)                                    04400000
         DC    X'00'                    COMMAND REJECT                  04420000
         DC    AL1(ERR612-ERR604-16)                                    04440000
         DC    X'2F'                    END OF TEST                     04460000
         DC    AL1(ERR611-ERR604-18)                                    04480000
         SPACE 1                                                        04484017
*        INTERVENTION REQUIRED                                     8655 04488017
ERR608   OI    IOBFL3(IOBRG),IOBENT     SET ENTRY FLAG             8655 04492017
         BC    15,ERR613                                           8655 04496017
         SPACE 1                                                        04500000
*        BUSOUT CHECK                                                   04520000
ERR609   TM    IOBFL3(IOBRG),IOBBOE     TEST IF BUSOUT FLAG IS ON       04540000
         BC    1,ERR611                 YES, SET LOGOUT                 04560000
         OI    IOBFL3(IOBRG),IOBBOE     SET BUSOUT FLAG                 04580000
         OI    IOBFL3(IOBRG),IOBENT     SET ENTRY FLAG             8655 04590017
         SVC   EXCPER                   ERROR EXCP                      04600000
         SVC   3                        RETURN                          04620000
         SPACE 1                                                        04621016
ERZERIB  L     ERPIBRG,IBPTR(COMREG)    PTR TO PTR TO PTR TO ERPIB CHAA 04622016
         L     ERPIBRG,0(ERPIBRG)       PTR TO PTR TO ERPIB        CCHA 04623016
         LTR   ERPIBRG,ERPIBRG          CCH IN SYSTEM              CCHA 04624016
         BC    8,ERR611                 NO-LOG OUT                 CCHA 04625016
         L     ERPIBRG,0(ERPIBRG)       PTR TO ERPIB               CCHA 04626016
ERCMPR   CH    UCBREG,2(ERPIBRG)        IS THIS ERPIB FOR PAP TP RDCCHA 04627016
         BC    8,ERZERO                 YES-ZERO ERPIB             CCHA 04628016
         SPACE 1                                                        04629016
         LA    ERPIBRG,8(ERPIBRG)       ADDR OF NEXT ERPIB         CCHA 04630016
         TM    ERPIBRG,ENDTBL           END OF ERPIB TABLE        CCHA  04631016
         BC    8+4+2,ERCMPR             NO-TEST NEXT ERPIB         CCHA 04632016
         SPACE 1                                                        04633016
         BC    1,ERR611                 YES-LOG OUT                CCHA 04634016
         SPACE 1                                                        04635016
ERZERO   XC    0(8,ERPIBRG),0(ERPIBRG)  ZERO ERPIB                 CCHA 04636016
         SPACE 1                                                        04640000
ERR611   OI    IOBFL3(IOBRG),IOBLOG     SET LOGOUT FLAG                 04660000
ERR612   OI    IOBFL3(IOBRG),IOBMSG     SET MSG TYPE FLAG               04680000
ERR613   LA    ERREG1,WTORTN            GET LOAD NAME TO WTO RTN.       04700000
         L     ERRETR,VECTXL(COMREG)    GET ADDR. TO XCTL RTN.          04720000
         BCR   15,ERRETR                XCTL TO WTO RTN.                04740000
         SPACE 1                                                        04760000
*        LINK TO THE INTERPRETER ROUTINE - THE BYTES FOLLOWING THE BALR 04780000
*        INDICATE IN WHAT ORDER THE BITS ARE TO BE TESTED (BIT 3 ON OF  04800000
*        THE CODE BYTE INDICATES STATUS) FOLLOWED BY AN INDEX VALUE THE 04820000
*        INTERPRETER USES TO RETURN TO THIS ROUTINE                     04840000
         SPACE 1                                                        04860000
ERR615   LR    SAVREG,BASREG            SAVE BASE ADDRESS               04880000
         L     BASREG,VECT68(COMREG)    GET ADDRESS TO INTERP. ROUTINE  04900000
ERR616   BALR  ERRLNK,BASREG            LINK TO INTERPRETER ROUTINE     04920000
         SPACE 1                                                        04940000
         DC    X'1C'                    CHANNEL DATA CHECK         CCHA 04950016
         DC    AL1(ERR625-ERR616-2)                                CCHA 04960016
         DC    X'1A'                    PROGRAM CHECK              CCHA 04970016
         DC    AL1(ERR618-ERR616-4)                                CCHA 04980016
         DC    X'1B'                    PROTECTION CHECK           CCHA 04990016
         DC    AL1(ERR618-ERR616-6)                                CCHA 05000016
         DC    X'17'                    UNIT EXCEPTION             CCHA 05010016
         DC    AL1(ERR619-ERR616-8)                                8655 05020017
         DC    X'19'                    INCORRECT LENGTH           CCHA 05030016
         DC    AL1(ERR619-ERR616-10)                               8655 05040017
         DC    X'2F'                    END OF TEST                CCHA 05050016
         DC    AL1(ERR620-ERR616-12)                               CCHA 05060016
         SPACE 1                                                        05070016
         SPACE 1                                                        05160000
*        PERMANENT ERROR                                                05180000
ERR618   NI    IOBFL1(IOBRG),X'FF'-IOBERR RESET IOB ERR FLAG            05200000
         SVC   EXCPER                   ERROR EXCP                      05220000
         SVC   3                        RETURN                          05240000
         SPACE 1                                                        05244017
*        UNIT EXCEPTION AND INCORRECT LENGTH                       8655 05248017
ERR619   TM    IOBFL3(IOBRG),IOBENT     PREV. ERR BUT CORRECTED    8655 05252017
         BC    8,ERR618                 NO,PERMANENT ERROR         8655 05256017
         SPACE 1                                                        05260000
*        ERROR CORRECTED                                                05280000
ERR620   NI    IOBFL1(IOBRG),X'FF'-IOBEXE-IOBSRS                   7884 05300017
*                                      RESET IOB EX,ERR,REST       7884 05320017
         MVI   IOBFL3(IOBRG),IOCLBT     CLEAR ERR COUNTS                05360000
ERR622   LA    ERREG1,STATUP            GET LOAD NAME TO STAT. UPDATE   05380000
         L     ERRETR,VECTXL(COMREG)    GET ADDRESS TO XCTL ROUTINE     05400000
         BCR   15,ERRETR                XCTL TO STATISTIC UPDATE RTN.   05420000
         SPACE 1                                                        05426016
ERR625   BC    15,ERR611                LOG OUT AFTER CH DATA CK   CCHA 05432016
         SPACE 1                                                        05440000
ERRCN1   DC    AL2(8)                   CSW ADJUSTING CONSTANT          05460000
ERRCN2   DC    AL2(10)                  MULTIPLIER CONSTANT             05480000
         END                                                            05500000
